godot-artnet/scripts/dmx_color.gd

extends Node2D

# Direct control Colored Light.
# Only One color for whole device.

@export var artnet:Node
@export var output:bool=true
@export_range(0,255,1) var master = 255

@export_range(1,512,1) var channel_offset=1

enum Model {cameo_clp_flatpro_18, robtertjuliat_dalis_861_fullmode8b}
@export var model: Model


	
var colormix=[]
	
var colorchannels=[]
var colorvalues=[]

var fixedchannels=[]
var fixedvalues=[]

func _ready() -> void:
	if (model==Model.cameo_clp_flatpro_18):
		colormix=[
			[1.0,0,0], #red
			[0,1.0,0], #green
			[0,0,1.0], #blue
			[1.0,1.0,1.0], #white
			[1.0,0.75,0], #amber
		]
		colorchannels=[3,4,5,6,7] #same order as colormix
		
		fixedchannels=[2,8]
		fixedvalues=[0,0]
	elif (model==Model.robtertjuliat_dalis_861_fullmode8b):
		#https://www.robertjuliat.com/PDF/Documents/DN41108200_m_DALIS_861.pdf
		colormix=[
			[1.0,0,0], #red
			[0,1.0,0], #green
			[0,1.0,1.0], #blue (looks cyan)
			[0.0,0.0,1.0], #royal blue  (looks more blue)
			[0,1.0,0.8], #cyan (looks more green)
			[1.0,0.75,0], #amber
			[1.0,1.0,1.0], #white
			[1.0,0.9,0.8], #warm white 
		]
		colorchannels=[2,3,4,5,6,7,8,9] #same order as colormix
		
		fixedchannels=[10,11,12,13]
		fixedvalues=[0,0,255,0]
		
	colorvalues.resize(colorchannels.size())
	

func _process(delta: float) -> void:
	var rgb=[modulate.r,modulate.g,modulate.b]
	
	colorvalues.fill(0.0)
	
	var passes=0
	while rgb[0]+rgb[1]+rgb[2]>0.01:
		passes+=1
		
		var cmixsums=[]
		for cmix in colormix:
			var colormix_min=matrixDivide(rgb,cmix).min()
			var resultrgb = matrixSubtract(rgb,matrixMult(cmix,colormix_min))
			cmixsums.append(matrixSum(resultrgb))
		var cmixsums_min=matrixMinIndex(cmixsums)
		var colormix_min=matrixDivide(rgb,colormix[cmixsums_min]).min()
		rgb = matrixSubtract(rgb,matrixMult(colormix[cmixsums_min],colormix_min))
		colorvalues[cmixsums_min]+=colormix_min
	
	#print("Result color mix:"+str(colorvalues)+" passes="+str(passes)+ " remaining error="+str(rgb[0]+rgb[1]+rgb[2]))
	
	
	if output:
		artnet.setDMXChannel(channel_offset-1+1,master) #master dimmer
	
	#artnet.setDMXChannel(channel_offset-1+2,0) #strobo
	#artnet.setDMXChannel(channel_offset-1+8,0) #macros
	
	var vi=0
	for v in colorvalues:
		if output:
			artnet.setDMXChannel(channel_offset-1+colorchannels[vi],v*255)
		vi+=1
		
		
	var fi=0
	for f in fixedvalues:
		if output:
			artnet.setDMXChannel(channel_offset-1+fixedchannels[fi],f)
		fi+=1
	
	
func matrixDivide(m1:Array,m2:Array) -> Array:
	var res=[]
	var i=0
	for m in m1:
		if (m==0 and m2[i]==0): #0/0 should be inf
			res.append(1.0/0)
		else:
			res.append(m/m2[i])
		i+=1
	return res
	
func matrixMult(m1:Array,p:float) -> Array:
	var res=[]
	for m in m1:
		res.append(m*p)
	return res
	
func matrixSubtract(m1:Array,m2:Array) -> Array:
	var res=[]
	var i=0
	for m in m1:
		res.append(m-m2[i])
		i+=1
	return res
	
func matrixSum(m1:Array) -> float:
	var res=0
	for m in m1:
		res+=m
	return res
	
func matrixMinIndex(m:Array) -> int:
	var min=0
	var i=0
	for e in m:
		if (m[i]<m[min]):
			min=i
		i+=1
	return min