hydroponic-controller/include/ec.h

#ifndef _EC_H_
#define _EC_H_

#include <Arduino.h>


bool ec_flag_measurement_available=false;

#define EC_PIN_RELAY_PROBE 27


//#define EC_PIN_ADC 4
#define EC_ADS_CHANNEL 0
#define EC_PIN_FREQ 5
#define EC_PWM_CH 0
#define EC_RESOLUTION 8
#define EC_FREQUENCY 5000

#define EC_CALIB_ARRAY_SIZE 64
uint16_t ec_calib_array[EC_CALIB_ARRAY_SIZE];
uint16_t ec_calib_array_pos=0;
#define EC_CALIB_READ_INTERVAL 100 //interval of reading adc value inside a measurement

#define EC_ARRAY_SIZE 64
uint16_t ec_array[EC_ARRAY_SIZE];
uint16_t ec_array_pos=EC_ARRAY_SIZE;
unsigned long last_measurement_ec=0;
#define EC_MEASUREMENT_INTERVAL 10000 //complete filtered measurement every x ms
  //One filtered measurement takes EC_READ_INTERVAL*EC_ARRAY_SIZE*4
#define EC_READ_INTERVAL 5 //interval of reading adc value inside a measurement

#define EC_RELAY_SWITCH_SETTLETIME 500  //time until voltage of ec circuit has settled

const uint16_t ec_centerADCvalue=1909; //adc value when probe resistance is equal to the range resistor (mean of both)

unsigned long ec_last_change_relay=0; //millis of last relay change

enum ECState{IDLE,MEASURE};

ECState ecstate=IDLE;

float ec_adc;
float ec_adc_adjusted; //adjusted for reference resistor
float ec_calib_adc;

float ec_reference_adc=5889; //adc reference value for the calibration resistor measurement

bool ec_measurementReady();
void ec_startMeasurement();
void ec_setRange(uint8_t range);
void ec_connectProbe(bool);
void ec_releaseRelay();

void ec_setup() {
  ledcSetup(EC_PWM_CH, EC_FREQUENCY, EC_RESOLUTION);
  ledcAttachPin(EC_PIN_FREQ, EC_PWM_CH);
  ledcWrite(EC_PWM_CH, 127); //50% duty cycle

  pinMode(EC_PIN_RELAY_PROBE,OUTPUT); //LOW=Calibration/idle, HIGH=Probe connected
  ec_releaseRelay();

}

void ec_loop(unsigned long loopmillis) {
  
  static unsigned long last_read_ec=0;

  switch (ecstate) {
    case IDLE:
      
      if (loopmillis>last_measurement_ec+EC_MEASUREMENT_INTERVAL && ecstate==IDLE) { //start measurement if idle
        last_measurement_ec=loopmillis;
        ec_startMeasurement();
        ec_connectProbe(true);
        Serial.println("Measuring EC");
        ecstate=MEASURE;
      }
      break;

    case MEASURE:
      if (ec_measurementReady()) {
        ec_releaseRelay();
        Serial.println("Finished EC");
        ec_adc=getMean(ec_array,EC_ARRAY_SIZE);
        if (isValueArrayOK(ec_calib_array,EC_CALIB_ARRAY_SIZE,0)){
          ec_calib_adc=getMean(ec_calib_array,EC_CALIB_ARRAY_SIZE);
          ec_adc_adjusted=mapf(ec_adc,0,ec_calib_adc,0,ec_reference_adc);
        }

        ec_flag_measurement_available=true;

        ecstate=IDLE;
      }
      
      break;

  }


  if (ec_array_pos<EC_ARRAY_SIZE) { //measurement running
    if (loopmillis>last_read_ec+EC_READ_INTERVAL) { //take reading into array
      last_read_ec=loopmillis;

      if (loopmillis>ec_last_change_relay+EC_RELAY_SWITCH_SETTLETIME) { //values have settled        
        uint16_t value = ADS.readADC(EC_ADS_CHANNEL);
        
        ec_array[ec_array_pos]=value;
        
        ec_array_pos++;
      }
    }
  }else{ //measurement not running, then take calibration readings
    if (loopmillis>last_read_ec+EC_CALIB_READ_INTERVAL) { //take reading into array
      last_read_ec=loopmillis;

      if (loopmillis>ec_last_change_relay+EC_RELAY_SWITCH_SETTLETIME) { //values have settled        
        uint16_t value = ADS.readADC(EC_ADS_CHANNEL);
        
        ec_calib_array[ec_calib_array_pos]=value;
        
        ec_calib_array_pos++;
        ec_calib_array_pos%=EC_CALIB_ARRAY_SIZE;

        
      }
    }
  }
  
}



void ec_startMeasurement() {
  ec_array_pos=0;
}

bool ec_measurementReady(){
  if (ec_array_pos>=EC_ARRAY_SIZE) { //reached end of both arrays
    return true;
  }else{
    return false;
  }
}


void ec_connectProbe(bool relay) {
  bool val=digitalRead(EC_PIN_RELAY_PROBE);
  if (val!=relay) { //write only if different
    digitalWrite(EC_PIN_RELAY_PROBE,relay);
    ec_last_change_relay=millis();
  }
}

void ec_releaseRelay() {
  digitalWrite(EC_PIN_RELAY_PROBE,LOW);
  ec_last_change_relay=millis();
}


#endif